ファイルパス制御 | VBA

'*******************************************************************************
' ファイルやフォルダーの存在確認
'  input  : FileName = ファイル名 (フルパス)
'  return : True  = あり
'           False = なし
'  note   :
'*******************************************************************************
Public Function Get_FileExists(FileName As String) As Boolean

    If Dir(FileName) <> "" Then
        Get_FileExists = True
    Else
        Get_FileExists = False
    End If

End Function

'*******************************************************************************
' ファイルパスを取得
'  input  : FileName = ファイル名 (フルパス)
'  return : ファイルパス
'  note   : "C:\Users\xxx\Documents\a.txt" ⇒ "C:\Users\xxx\Documents"
'*******************************************************************************
Public Function Get_FilePath(FileName As String) As String

    Get_FilePath = Left(FileName, InStrRev(FileName, "\") - 1)

End Function

'*******************************************************************************
' ファイル名を取得
'  input  : FileName = ファイル名 (フルパス)
'  return : ファイル名
'  note   : "C:\Users\xxx\Documents\a.txt" ⇒ "a.txt"
'*******************************************************************************
Public Function Get_FileName(FileName As String) As String

    Get_FileName = Mid(FileName, InStrRev(FileName, "\") + 1)

End Function

'*******************************************************************************
' ベース名を取得
'  input  : FileName = ファイル名 (フルパス)
'  return : ベース名
'  note   : "C:\Users\xxx\Documents\a.txt" ⇒ "a"
'*******************************************************************************
Public Function Get_BaseName(FileName As String) As String

    Dim Tmp As String

    Tmp = Mid(FileName, InStrRev(FileName, "\") + 1)
    Get_BaseName = Left(Tmp, InStrRev(Tmp, ".") - 1)

End Function

'*******************************************************************************
' ファイルの拡張子を取得
'  input  : FileName = ファイル名 (フルパス)
'  return : 拡張子
'  note   : "C:\Users\xxx\Documents\a.txt" ⇒ "txt"
'*******************************************************************************
Public Function Get_FileExt(FileName As String) As String

    Get_FileExt = Right(FileName, Len(FileName) - InStrRev(FileName, "."))

End Function

'*******************************************************************************
' ファイルの更新日時を取得
'  input  : FileName = ファイル名 (フルパス)
'  return : 更新日時
'  note   :
'*******************************************************************************
Public Function Get_LastWriteTime(FileName As String) As Date

    Get_LastWriteTime = FileDateTime(FileName)

End Function